대부분 DBMS는 테이블에 자동증가필드를 설정할 수 있습니다.

자동증가필드는 테이블에 새로운 데이터 입력 시 필드의 값을 자동으로 증가해 유효한 값을 갖도록 하는 것이 목적입니다.

자동증가필드 설정은, 

SQLServer(MSSQL)은 필드에 IDENTITY 속성을 설정, MySQL은 필드에 auto_increment 속성을 설정해 지원합니다.

오라클과 인터베이스는 필드의 속성을 설정하는 방식을 지원하지 않습니다.

오라클은 Sequence, 인터베이스(그리고 Firebird)는 Generator 생성 후 트리거(Before Insert)와 연동해 자동증가 필드를 적용할 수 있습니다.

• 인터베이스 데이터베이스와 테이블 생성 - 하단 "기본 키 자동증가 설정" 참고

이 글에서는, 인터베이스 테이블의 자동증가필드를 설정하고, 테이블에 데이터 추가 후 갱신된 자동증가필드 값을 가져오는 방법을 설명 합니다.

다음 코드는 새로운 데이터 추가 후 자동증가필드 값을 가져오는 코드입니다.

코드를 실행하면 2가지 문제를 만나게 됩니다.

procedure TForm1.Button3Click(Sender: TObject);
begin
  FDQuery1.Append;
  FDQuery1.FieldByName('BOOK_TITLE').AsString := 'test';
  FDQuery1.FieldByName('BOOK_AUTHOR').AsString := 'test';
  FDQUery1.Post;

  ShowMessage(IntToStr(FDQuery1.FieldByName('BOOK_SEQ').AsInteger));
end;

코드를 실행하면 먼저 다음과 같은 오류를 만나게 됩니다.

BOOK_SEQ 필드는 자동증가필드로, 필드에 값이 없다는 오류입니다. 자동증가필드는 자동으로 값이 채워지도록 설정해야 합니다.

FireDAC 데이터셋 컴포넌트(TFDQuery, TFDTable, TFDStoredProc)에 자동증가필드를 설정하면 해결할 수 있습니다.

• UpdateOptions > AutoIncFields

자동증가필드 설정 시 새로운 레코드 추가 시 해당 필드에 임의의 음수 값이 자동 설정됩니다.(-1 > -2 > -3 > ...)

그리고, 다시 실행하면 다음과 같이 음수 값이 표시됩니다. 즉, 자동증가필드값이 갱신되지 않습니다.

인터베이스의 경우 제너레이터로 자동증가필드가 채워져 제너레이터이름을 지정하면, 자동증가필드 값이 갱신됩니다.

• UpdateOptions > GeneratorName

참고로,

오라클도 시퀀스를 지정해 같은 동작을 할 수 있을 것으로 생각됩니다. 하지만 개발환경이 되지 않아 테스트 해보지 못했습니다.

(오라클 환경이 되시는 분이 계시면 테스트 후 결과 알려주시면 감사하겠습니다.)

MySQL, SQLServer 등 자동증가필드를 필드 속성으로 지정하는 경우 위 작업을 별도로 진행하지 않아도 자동 갱신됩니다.

REST API 관련 컨설팅 중 학습한 내용을 공유합니다.

고객사의 요청으로 VendHQ 사의 REST 서비스와 연동을 진행했습니다.

OAuth 2.0 연동 중 웹브라우저 이슈가 있어 해결방안을 공유합니다.

해당 이슈는 VCL과 FMX 두가지 TWebBrowser가 동일합니다.

크로미움 기반 웹브라우저 컴포넌트 설치

CEF4Delphi는 크로미움 기반 웹브라우저 써드파티 컴포넌트로 오픈소스로 진행됩니다.

깃허브 저장소를 통해 제공하고 있습니다.

• https://github.com/salvadordf/CEF4Delphi

CEF4Delphi를 사용하려면 컴포넌트 설치 후 실행(및 배포) 시 크로미움 관련 라이브러리들을 함께 배포해야 합니다.

CEF4Delphi 다운로드

CEF4Delphi 깃허브 페이지에서 컴포넌트를 다운로드 합니다.(Clone or download > Download ZIP)

다운로드 받은 파일을 압축 해제 후 적절한 라이브러리 저장 경로에 이동합니다.(해당 경로의 패키지를 설치하고 델파이에 링크하게 됩니다.)

CEF4Delphi 컴포넌트 설치

델파이를 실행하고 다운로드 받은 파일들에서 .\packages\CEF4Delphi.dpk 패키지 프로젝트 파일을 엽니다.

프로젝트에서 오른쪽 마우스 클릭 후 팝업 메뉴에서 인스톨 메뉴를 선택해 설치합니다.

라이브러리 패스 추가

패키지 설치 후 CEF4Delpih 소스코드를 델파이 라이브러리 패스에 추가합니다.

델파이 라이브러리 화면을 표시합니다.

Tools > Options, Language > Delphi Options > Library

플랫폼을 선택 후 Library path에 CEF4Delphi 소스 디렉토리를 추가합니다.

CEF4Delphi 프로그램 실행

관련/참고 링크

• OAuth 2.0 연동 - 카카오 API(카카오톡 프로필)
  

REST API 관련 컨설팅 중 학습한 내용을 공유합니다.

한 고객사의 요청으로 Unleashed 사의 REST 서비스와 연동을 진행했습니다.

그 과정 중 HMAC(해시 기반 메시지 인증 코드) 구현 과정을 공유합니다.

HMAC은 Unleashed 사 뿐아니라 AWS의 REST API 연동에도 사용되는 등 많은 REST 서비스에 구현되는 내용입니다.

위에서 API 키는 서비스 등록시 발급받은 값입니다.

쿼리 스트링은 URL 중 "?" 뒤의 문자열입니다. 예를 들면

Customers?customerCode=ACME 중 customerCode=ACME가 쿼리 스트링입니다.

HMAC-SHA256은 다음과 같이 구현할 수 있습니다.

HMAC-SHA256

다음 샘플은 쿼리스트링(ProductCode=XXX)와 API Key(UNLEASHED_API_KEY: 상수)를 이용해 HMAC을 SHA256으로 시그니처를 생성해 HTTP 해더에 추가하는 내용입니다.

uses
  System.Hash,          // sha256
  System.NetEncoding;   // base64

var
  signature: string;
  param: string;
begin
  param := 'ProductCode=' + AProductCode;

  // PHP: base64_encode(hash_hmac('sha256', $request, $key, true));
  signature := TBase64Encoding.Base64.EncodeBytesToString(
                  THashSHA2.GetHMACAsBytes(param, UNLEASHED_API_KEY, SHA256));

  RESTRequest1.Params.AddItem('api-auth-id', UNLEASHED_API_ID, pkHTTPHEADER);
  RESTRequest1.Params.AddItem('api-auth-signature', signature, pkHTTPHEADER, [poDoNotEncode]);
end;

추가 학습할 내용

HMAC 인증외에 OAuth 2.0 인증도 많이 사용됩니다.

다음 글을 통해 OAuth 2.0을 통해 카카오 API에 연동하는 내용을 살펴볼 수 있습니다.

• OAuth 2.0 연동 - 카카오 API(카카오톡 프로필)

• REST API 이해하기
  
• REST API 서버 개발하기(엔드포인트 구현, RAD 서버 이용)
• REST API 클라이언트 개발하기(REST Client 이용)
• 데이터셋 기반 REST API 개발하기

이 글에서는 OAuth 2.0을 이용해 카카오 API와 연동하는 방법을 델파이를 통해 알아봅니다.

이 글을 통해 카카오톡 프로필 정보와 사진을 델파이 애플리케이션에서 불러오는 예제를 작성할 수 있습니다.

OAuth 2.0

API(또는 서비스) 이용 시 인증(Authentication)과 리소스(제공 서비스)에 대한 권한부여(Authorization)는 필수사항입니다. 인증과 권한부여의 대표적인 방법 중 하나가 OAuth입니다.

OAuth는 서버와 클라이언트 사이에 인증을 완료 시 권한부여의 결과로 엑세스 토큰(Access Token)을 발급하고, 이 엑세스 토큰을 이용해 클라이언트는 API(또는 서비스)에 접근 및 서비스를 요청하게 됩니다. 서버는 엑세스 토큰 기반으로 서비스와 권한에 대한 접근 여부를 판단해 데이터를 제공합니다.

OAuth는 현재 2.0 버전을 제공하며, 카카오, 구글, 페이스북에서 OAuth 2.0을 통해 서비스에 대한 인증 및 권한부여를 사용하고 있습니다.

OAuth 2.0에 대한 내용은 자세한 내용은 이 글의 하단 "관련/참고 링크"를 통해 알아볼 수 있습니다.

OAuth 2.0 사용 시 API 인증 흐름

다음 그림은 카카오 API 서비스에 접근하기 위해 OAuth 2.0 인증의 흐름을 7 단계로 나타냅니다.

0, 카카오 서비스를 이용하려면 사전에 앱을 등록 후 앱의 API 키를 발급받아야 합니다.

1, 카카오 서비스에 접근하기 위해 카카오 로그인 페이지를 웹브라우저에 표시합니다.

2, 사용자는 로그인 페이지에 ID, 비밀번호를 입력해 인증을 요청합니다.

3, 카카오 인증서버는 사용자를 인증하고 사용자 인증완료 페이지로 리다이렉션합니다. 이때 인증 코드를 함께 전달합니다.

4, 애플리케이션은 리다이렉션 URL을 분석해 인증코드를 획득합니다.

5, 애플리케이션은 카카오 인증서버에 제대로 인증된 사용자인지 확인 요청을 합니다.

6, 카카오 인증서버는 인증된 사용자임을 확인하고, 엑세스 토큰(Access Token)을 발급합니다.

7, 애플리케이션은 발급받은 엑세스 토큰을 이용해 카카오 API 서버에 접근합니다.

델파이로 OAuth 2.0 구현

위의 API 흐름을 카카오 OAuth와 카카오톡 프로필과 연동하는 과정을 델파이를 통해 구현해봅니다.

다음과 같은 데모를 구현합니다.

구현 과정은 크게 준비 + 3단계로 구분됩니다.

[준비] 카카오 서비스에 앱 등록 및 API 키 발급

[1단계] 인증페이지에 로그인 해 인증코드 취득

[2단계] 인증코드로 엑세스 토큰 취득

[3단계] 엑세스 토큰으로 서비스 접근

[준비] 앱 등록 및 API 키 발급

• https://developers.kakao.com/docs/restapi#앱-생성

앱 만들기

앱을 생성하면 다음 그림과 같이 키가 생성됩니다. 우리는 REST API 키를 사용할 것이므로 REST API 키를 복사해 보관해 둡니다.

하단의 설정 링크를 눌러 상세 설정화면으로 이동합니다.

플랫폼 추가

기본 정보 화면에서 [플랫폼 추가] 버튼을 누릅니다.

웹을 선택하고, 여러분들의 사이트 도메인을 입력합니다. [추가] 버튼을 누릅니다.

사이트 도메인과 Redirect Path를 확인 후 [저장] 버튼을 누릅니다.

사이트 도메인 + Redirect Path(저의 경우 http://hjf.pe.kr/oauth)는 실제 존재하는 페이지를 지정해야 합니다.

이 페이지는 카카오 로그인 후 리다이렉션되는 페이지로 아무 기능이 없더라도 페이지를 생성해 놔야 합니다.(페이지가 없으면 404 not found 오류가 발생합니다.)

운영하는 서비스가 없이 테스트 목적이라면 제 도메인을 등록하도록 합니다.(하지만 언제든 페이지를 삭제할 수 있으니 테스트 목적으로만 사용하시기 바랍니다.)

사용자 관리 활성화

사용자 관리 메뉴로 이동 후, 사용자 관리를 활성화 합니다. 

우리는 카카오 프로필 정보에 접근할 것이므로 프로필 정보 하단의 수집목적을 적절히 입력하고, [설정] 버튼을 클릭합니다.

앱 등록 및 API 키 발급 과정이 완료되었습니다.

[준비] 프로젝트 생성 및 화면 구성

• https://developers.kakao.com/docs/restapi/user-management#로그인

[Request]

[Response]

Request와 같이 페에지를 표시 후 사용자 로그인 성공 시 Response와 같이 redirect_url로 페이지 이동됩니다. 이때 인증 코드(authorize_code)가 함께 전달됩니다.

Button1 클릭 이벤트에 다음과 같이 코드를 입력합니다.

procedure TForm1.Button1Click(Sender: TObject);
var
  url: string;
  param: string;
begin
  Edit1.Text := '';

  url := 'https://kauth.kakao.com';
  param := '/oauth/authorize?client_id={app_key}&redirect_uri={redirect_uri}&response_type=code';
  param := param.Replace('{app_key}', API_KEY);
  param := param.Replace('{redirect_uri}', 'http://hjf.pe.kr/oauth');

  WebBrowser1.URL := url + param;
  WebBrowser1.Navigate;
end;

API_KEY는 상수로 implementation 위에 등록했습니다.(앱 생성 시 등록한 REST API 키를 XXXXX 대신 입력합니다.)

const
  // 카카오톡 개발자 사이트에서 앱 등록 후 API키를 등록하세요.
  API_KEY = 'XXXXXXXXXXXXXXXXX';

implementation

로그인 성공 시 인증코드 수신하는 내용을 작성합니다. WebBrowser1의 OnDidFinishLoad(페이지 전환 완료) 이벤트 생성 후 다음 코드를 입력합니다.

procedure TForm1.WebBrowser1DidFinishLoad(ASender: TObject);
var
  url: string;
  code: string;
begin
  Memo1.Lines.Add('WebBrowser1DidFinishLoad' + WebBrowser1.URL);

  if Edit1.Text <> '' then
    Exit;

  url := WebBrowser1.URL;

  if Pos('code=', url) > 0 then
  begin
    code := Copy(url, Pos('code=', url) + Length('code='), Length(url));
    if Pos('&', code) > 0 then
      code := Copy(code, 1, Pos('&', code)-1);

    Edit1.Text := code;
  end;
end;

제일 첫줄은 URL을 메모에 출력하는 로그성 기능입니다.

13~20줄에서 변경된 URL 중 인증코드 파라메터("code=")가 있는 경우 인증코드 값을 가져와 Edit1.Text에 설정합니다.

[2단계] 엑세스 토큰 취득

인증코드를 받은 다음, 이를 이용해 실제로 API를 호출할 수 있는 엑세스 토큰(Access Token)을 받아오는 내용을 구현합니다.

• https://developers.kakao.com/docs/restapi/user-management#로그인

[Request]

[Response]

위 문서와 같이 POST로 요청 후 받은 응답 값(json 포맷)에서 access_token 값을 취득해야 합니다.

이 기능은 REST Client 프레임워크를 이용해 개발합니다.

화면에 TRESTClient, TRESTRequest, TRESTResponse 3개의 컴포넌트를 추가 합니다.

[3. 엑세스 토큰 취득] 버튼의 클릭 이벤트에 다음과 같이 구현합니다.
(아래 과정은 디자인 타임에서 컴포넌트에 직접 설정해도 무관합니다.)

procedure TForm1.Button2Click(Sender: TObject);
var
  token: string;
begin
  RESTClient1.BaseURL := 'https://kauth.kakao.com/';

  RESTRequest1.Resource := 'oauth/token';
  RESTRequest1.Method := rmPOST;
  RESTRequest1.Params.Clear;
  RESTRequest1.Params.AddItem('grant_type',   'authorization_code');
  RESTRequest1.Params.AddItem('client_id',    API_KEY);
  RESTRequest1.Params.AddItem('redirect_uri', 'http://hjf.pe.kr/oauth');
  RESTRequest1.Params.AddItem('code',         Edit1.Text);

  RESTRequest1.Execute;

  Memo1.Lines.Text := RESTResponse1.Content;

  if RESTResponse1.JSONValue.TryGetValue<string>('access_token', token) then
    Edit2.Text := token;
end;

개발가이드와 같이 요청 정보를 RESTClient와 RESTRequest 컴포넌트의 속성과 파라메터에 설정한 후 실행(RESTRequest1.Execute;) 후 받은 응답에서 엑세스 토큰(access_token)을 받아 Edit2.Text에 설정합니다.

엑세스 토큰을 받는 과정까지 마쳤습니다. 이제 엑세스 토큰을 이용해 카카오톡 프로필 정보에 접근해 데이터를 연동 할 수 있습니다.

[3단계] 카카오톡 프로필과 연동

엑세스 토큰을 얻었다면 카카오톡 프로필 서비스와 연동해 프로필 정보를 받아올 수 있습니다.

카카오 개발가이드 중 카카오톡-프로필요청 부분의 문서를 참고해 개발합니다.

• https://developers.kakao.com/docs/restapi/kakaotalk-api#프로필-요청

procedure TForm1.Button3Click(Sender: TObject);
var
  Url: string;
  Stream: TMemoryStream;
begin
  OAuth2Authenticator1.AccessToken := Edit2.Text;

  RESTClient2.BaseURL := 'https://kapi.kakao.com/';
  RESTClient2.Authenticator := OAuth2Authenticator1;

  RESTRequest2.Client := RESTClient2;
  RESTRequest2.Response := RESTResponse2;

  RESTRequest2.Resource := 'v1/api/talk/profile';
  RESTRequest2.Execute;

  Memo1.Lines.Text := RESTResponse2.Content;

  Url := RESTResponse2.JSONValue.GetValue<string>('profileImageURL');

  RESTClient3.BaseURL := Url;
  RESTClient3.Authenticator := OAuth2Authenticator1;
  RESTRequest3.ExecuteAsync(procedure
    begin
      Stream := TMemoryStream.Create;
      try
        Stream.WriteData(RESTResponse3.RawBytes, RESTResponse3.ContentLength);
        ImageControl1.Bitmap.LoadFromStream(Stream);
      finally
        Stream.Free;
      end;
    end
  );
end;

(해당 내용은 모든 데이터셋(TDataSet을 상속받은 컴포넌트) 즉, FireDAC, dbExpress, dbGo(ADO) 등에 적용할 수 있습니다.)

대부분의 DBMS에서 Blob(Binary Large object) 타입의 컬럼을 만들 수 있습니다. 이 컬럼에는 이미지등의 큰 바이너리 데이터를 취급할 수 있습니다.

아래 코드는 Blob 컬럼에서 이미지를 읽고, 쓰는 델파이 예제입니다.

Blob 컬럼에 이미지 데이트 쓰기

var
  wic: TWICImage; // Microsoft Windows Imaging Component
  Stream: TMemoryStream;
begin
  Stream := TMemoryStream.Create;
  try
    Image1.Picture.SaveToStream(Stream);
    qryPhoto.Edit; // 데이터셋 수정
    (qryPhoto.FieldByName('PHOTO_PHOTO') as TBlobField).LoadFromStream(Stream);
    qryPhoto.Post;
  finally
    Stream.Free;
  end;
end;

Blob 컬럼에서 이미지 데이터 읽기

var
  wic: TWICImage; // Microsoft Windows Imaging Component
  Stream: TMemoryStream;
begin
  Stream := TMemoryStream.Create;
  wic := TWICImage.Create;
  try
    (qryPhoto.FieldByName('PHOTO_FIELD') as TBlobField).SaveToStream(Stream);
    if Stream.Size > 0 then
    begin
      try
        wic.LoadFromStream(Stream);
        Image1.Picture.Assign(wic);
      except
      end;
    end;
  finally
    Stream.Free;
    wic.Free;
  end;
end;

위에서 사용한 TWICImage는 Microsoft Windows Imaging Component를 캡슐화한 클래스로, 다양한 이미지 형식(Bitmap, JPEG, PNG, GIF, TIFF 등)을 로드할 수 있는 컨테이너 입니다.(http://docwiki.embarcadero.com/Libraries/en/Vcl.Graphics.TWICImage)

SQL 작성 시 아래와 같이 파라메터를 많이 이용합니다.

SELECT * FROM EMPLOYEE WHERE EMP_ID = :EMP_ID

하지만, SQL을 로그로 기록할 경우 파라메터 명(:EMP_ID) 대신 파라메터 값이 들어가야 할 경우 아래와 같이 파라메터 값이 적용된 SQL을 만들어 사용할 수 있습니다.

procedure TForm1.Button1Click(Sender: TObject);
var
  I: Integer;
  SQLStr, ParamName, ParamValue: string;
begin
  Query1.Close;
  Query1.ParamByName('Name').AsString := '홍길동';
  Query1.ParamByName('JUNHYEONG').AsString := '2';
  Query1.ParamByName('yundo').AsString := '2016';
  Query1.Open;

  SQLStr := Query1.SQL.Text;
  for I := 0 to Query1.ParamCount - 1 do
  begin
    ParamName := ':' + Query1.Params[I].Name;
    ParamValue := Query1.Params[I].AsString;
    if Query1.Params[I].DataType in [ftString, ftWideString, ftMemo, ftWideMemo] then
      ParamValue := '''' + ParamValue + '''';
    SQLStr := SQLStr.Replace(ParamName, ParamValue);
  end;

  Memo1.Lines.Text := SQLStr;
end;

위와 같이 처리하면 메모에 아래와 같이 파라메터 명에 파라메터 값이 치환된 쿼리가 표시됩니다.

select *

from IPSI_MAST

where MAST_SUHEOM_BUNHO like '' || '%'

   and MAST_NAME like '홍길동' || '%'

   and MAST_JIMANG = '0'

   AND MAST_GUBUN = '2' 

   and MAST_JUNHYEONG like '2' || '%'

   and MAST_YUNDO ='2016'

order by MAST_SUHEOM_BUNHO

FireDAC의 TFDDataSet.MergeDataSet 메소드를 이용해 구조가 같은(또는 확장된) 데이터셋을 병합해 하나의 데이터셋을 구성할 수 있습니다.

제가 테스트한 목적은, 

데이터스냅으로 데이터량이 많은 데이터 중 일부분 데이터만 가져오고, 필요한 경우 추가로 가져와 병합(페이징 기능 구현) 할 목적으로 테스트 진행해 봤습니다.

TFDDataSet.MergeDataSet

TFDDataSet.MergeDataSet 데모

해당 데모는 왼쪽에 표시되는 3개 데이터셋(memList, memList2, memDetail)을 병합해 오른쪽에 표시되는 데이터셋(memMerge)으로 병합합니다.

병합할 대상 데이터는 같은 구조(ID, Name)의 데이터셋 2개와 확장된 구조(ID, Name, addr)를 데이터셋을 병합합니다.

작성하며 주의할 점은, 

1. 병합해 넣을 데이터셋(memMerge)에 기본키가 설정되어 있어야 합니다. => 아래 코드에서 "memMerge.Table.PrimaryKey := memDetail.Table.PrimaryKey;"
2. 필드 종류가 다른 데이터셋(memDetail)을 병합할 경우, 병합할 데이터셋(memMerge)에 데이터가 있을 경우 메타데이터를 변경할 경우(mmMerge) 코드 내부에서 데이터셋 메타데이터(필드 정보)를 재 생성 함. 이때 기본키가 설정되지 않아 위 1번 오류 발생 -> 미리 필드를 생성 후 mmMerge 호출하지 말 것(필드 종류가 다를 경우에 한함)

procedure TForm1.Button1Click(Sender: TObject);
begin
  // 필드 추가
  memList.FieldDefs.Add('ID', ftInteger, 0, False);
  memList.FieldDefs.Add('Name', ftString, 20, False);
  memList.CreateDataSet;

  memList2.FieldDefs.Add('ID', ftInteger, 0, False);
  memList2.FieldDefs.Add('Name', ftString, 20, False);
  memList2.CreateDataSet;

  memDetail.FieldDefs.Add('ID', ftInteger, 0, False);
  memDetail.FieldDefs.Add('Name', ftString, 20, False);
  memDetail.FieldDefs.Add('addr', ftString, 50, False);
  memDetail.CreateDataSet;

  // 데이터 추가
  memList.Open;
  memList.AppendRecord([1, '김현수']);
  memList.AppendRecord([2, '홍길동']);
  memList.AppendRecord([3, '유관순']);

  memList2.Open;
  memList2.AppendRecord([4, '김원경']);
  memList2.AppendRecord([5, '박범용']);

  memDetail.Open;
  memDetail.AppendRecord([1, '김현수', '인천']);

  // Field 복사: 미리 복사하지 않으면 Detail 머지 시 PK 설정되지 않음
  memMerge.MergeDataSet(memDetail, dmNone, mmMerge);
  // 병합해 넣을 데이터셋(memMerge)에 기본키가 설정되어 있어야 함. 기본키가 없으면 'no destination key defined' 오류 발생
  memMerge.Table.PrimaryKey := memDetail.Table.PrimaryKey;
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  memMerge.MergeDataSet(memList, dmDataMerge, mmNone);
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
  memMerge.MergeDataSet(memList2, dmDataMerge, mmNone);
end;

procedure TForm1.Button5Click(Sender: TObject);
begin
  memMerge.MergeDataSet(memDetail, dmDataMerge, mmNone);
end;

• http://docwiki.embarcadero.com/Libraries/Seattle/en/FireDAC.Comp.DataSet.TFDDataSet.MergeDataSet
  
• http://docwiki.embarcadero.com/Libraries/Seattle/ja/FireDAC.Stan.Intf.TFDMergeDataMode
• http://docwiki.embarcadero.com/Libraries/Seattle/ja/FireDAC.Stan.Intf.TFDMergeMetaMode

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

8회차에서는 메모리 기반 데이터셋인 TFDMemTable에 대해 알아봅니다.

TFDMemTable은 메모리 기반 데이터셋입니다. 즉, 데이터베이스 연결 없이 파일 데이터나 코드로 추가한 데이터를 메모리에 올려 데이터셋의 기능(필터링, 정렬 등)을 사용할 수 있습니다.

TFDMemTable은 아래 기능을 할 수 있습니다.

• 디자인타임과 런타임 시 파일 불러오기(Load File), 파일로 내보내기(Save File), 다른 데이터셋의 데이터가져오기(Assign Data) 기능 사용
• 런타임 시 파일과 스트림으로 데이터 내보내기, 불러오기 기능을 사용할 수 있으며, JSON, XML, Binary 포맷 선택 가능
• 멀티티어 애플리케이션(REST 클라이언트, 데이터스냅 등)에서 수신 데이터를 보관하는 데이터셋 역할
• 내부에서 데이터 보관할 시 컬랙션객체(TList, TStringList) 대신 메모리테이블 사용 시 데이터셋의 기능(UI 컨트롤에 데이터바인딩, Local SQL, 필터링, 정렬 등)을 사용해 다양한 기능 손쉽게 구현가능
• Local SQL을 이용해 메모리테이블(데이터셋)에서 쿼리 실행
• ETL 기능으로 다른 데이터소스(텍스트, CSV 등)에서 가져온 데이터 보관

FDMemTable1.SaveToFile(Path, sfJSON);

// 파일에서 불러오기
FDMemTable1.SaveToFile(FilePath, sfJSON);

// Create Field Definitions
FDMemTable1.FieldDefs.Add('ID', ftInteger, 0, False);
FDMemTable1.FieldDefs.Add('Name', ftString, 20, False);
FDMemTable1.CreateDataSet;
 
// Append data
FDMemTable1.Open;
FDMemTable1.AppendRecord([1, 'Jim']);
 
// Load from another DataSet
FDMemTable1.CopyDataSet(DataSet1, [coStructure, coRestart, coAppend]);

C++ 

// Create Field Definitions
FDMemTable1->FieldDefs->Add("ID", ftInteger, 0, False);
FDMemTable1->FieldDefs->Add("Name", ftString, 20, False);
FDMemTable1->CreateDataSet();
 
// Append Data
FDMemTable1->Open();
FDMemTable1->Append();
FDMemTable1->FieldByName("ID")->AsInteger = 1;
FDMemTable1->FieldByName("Name")->AsString = "Jim";
FDMemTable1->Post();
 
// Load from another DataSet
FDMemTable1->CopyDataSet(DataSet1, TFDCopyDataSetOptions() << coStructure << coRestart << coAppend);

TFDMemTable 샘플 프로그램

이 샘플에서는 TFDMemTable의 데이터를 디자인 타임 시 로드해 JSON 포맷으로 변경하고 다시 JSON 포맷을 TFDMemTable에 로드하는 기능을 구현했습니다.

[샘플코드 받기 - 데브기어 github 페이지]

메모리테이블 데이터를 JSON으로 내보내기, JSON 데이터를 메모리테이블로 불러오기

procedure TForm1.Button1Click(Sender: TObject);
var
  StrStream: TStringStream;
begin
  StrStream := TStringStream.Create;
  try
    DM.FDMemTable1.SaveToStream(StrStream, sfJSON); // uses FireDAC.Stan.Intf
//    DM.FDMemTable1.SaveToFile(FilePath, sfJSON);
    DM.FDMemTable1.EmptyDataSet;
    Memo1.Lines.Text := StrStream.DataString;
  finally
    StrStream.Free;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  StrStream: TStringStream;
begin
  StrStream := TStringStream.Create(Memo1.Lines.Text);
  try
    DM.FDMemTable1.LoadFromStream(StrStream, sfJSON); // uses FireDAC.Stan.Intf
//    DM.FDMemTable1.SaveToFile(FilePath, sfJSON);
  finally
    StrStream.Free;
  end;
end;

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

9회차에서는 쿼리 결과에서 검색하고, 조인할 수 있는 Local SQL에 대해 알아봅니다.

Local SQL은 DB로부터 애플리케이션의 메모리 상으로 가져온 데이터(데이터셋: TDataSet을 상속받은 객체)를 대상으로 다시 SQL 쿼리를 할 수 있는 기능입니다.

Local SQL은 아래와 같이 사용할 수 있습니다.

• 여러 이기종 DB들에 대한 쿼리 : 다양한 DB에서 가져온 여러 데이터셋을 대상으로 원하는 데이터 쿼리(조인 가능)
• 인 메모리 데이터베이스 : TFDMemTable은 메모리상에 있는 데이터셋의 역할
• 오프라인 모드 쿼리 : 원격 DB에 연결할 수 없는 경우에도, 이미 가져온 데이터셋을 대상으로 쿼리 실행
• 데이터스냅 클라이언트 쿼리 : 데이터스냅 서버(미들웨어)에서 받아온 데이터셋을 대상으로 쿼리 실행
• 간편한 마이그레이션 : 애플리케이션 내에서 써드파티를 통해 가져온 데이터셋 객체를 대상으로 쿼리 실행

Local SQL 사용을 위한 FireDAC 컴포넌트 구성

• TFDConnection의 DriverName을 SQLite로 설정합니다.(FireDAC의 Local SQL 엔진으로 SQLite 드라이버를 사용합니다.)
• TFDLocalSQL과 TFDQuery 컴포넌트의 Connection을 위의 TFDConnection으로 설정
• TFDLocalSQL 컴포넌트의 DataSets 컬랙션(속성)에 조회할 데이터셋(TDataSet을 상속받은 객체)을 등록

Local SQL의 설정의 자세한 내용은 엠바카데로 기술문서 - Local SQL (FireDAC) 페이지를 참고하시기 바랍니다.

Local SQL 샘플 프로그램

• 총 5 종류의 서로다른 데이터를 대상으로 쿼리
• dbExpress : dbExpress를 이용해 데이터베이스에서 가져온 데이터
• REST CDS : REST Client를 이용해 웹서비스에서 가져온 데이터
• IBX : IBX를 이용해 인터베이스 DB에서 가져온 데이터
• MemTable from Code : 코드로 직접 만든 로컬 데이터
• ADO & Access : ADO 기술을 이용해 엑세스 DB에서 가져온 데이터
• FDLocalSQL1의 DataSets 컬랙션에는 5개의 데이터셋을 검색 대상으로 등록
• 
• FDQuery1에서는 FDLocalSQL1.DataSets에 등록된 데이터셋 대상으로 SQL 쿼리를 작성해 검색할 수 있습니다.

SELECT 
  sales.order_status, 
  customers.customer,
  regions.RegionDescription, 
  rest.name as REP
FROM rest 

INNER JOIN RestSalesReps 
ON rest.id = RestSalesReps.RestID

INNER JOIN Sales
ON RestSalesReps.Sales_Rep = Sales.Sales_REP

INNER JOIN customers
ON sales.cust_no = customers.cust_no

LEFT OUTER JOIN regions
ON regions.RegionID = RestSalesReps.RestID

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

1회차에서는 FireDAC을 소개하고 연결하는 과정으로 진행합니다.

FireDAC은 델파이와 C++빌더에서 멀티-디바이스 데이터베이스 애플리케이션을 개발할 수 있는 범용(Universal) 데이터 엑세스 컴포넌트입니다. 

FireDAC은 통합 API를 사용해 다양한 데이터베이스를 동일한 코드로 제어할 수 있습니다. 그렇기 때문에 개발자는 데이터베이스를 신경쓰지 않고 애플리케이션 개발에 집중할 수 있고, DBMS 변경 시 대부분의 코드를 재사용할 수 있습니다. 그 뿐아니라 FireDAC은 데이터베이스 별 고유기능을 사용하고, 최적의 성능을 발휘할 수 있도록 데이터베이스 별 네이티브 드라이버를 지원합니다.

또한 기술적으로 아래의 장점을 제공합니다.

• 30배 빠른 데이터 입력이 가능한 Array DML
• DBMS의 사용내역을 추적하고 모니터링
• 엑셀형식으로 내보내고, 가져오기 기능을 개발할 수 있는 Batch Move
• DB에서 가져온 메모리상의 데이터를 대상으로 쿼리할 수 있는 Local SQL
• 이 외의 기술적인 장점은 아래의 FireDAC Skill Sprints 동영상과 샘플로 고급기능 활용하기 시리즈로 직접 확인하시기 바랍니다. 

2. FireDAC으로 DBMS 사용 내역 추적, 모니터링 하기

FireDAC 추적기능을 이용하면 애플리케이션과 데이터베이스 사이의 통신내용을 상세하게 보거나 기록할 수 있습니다. 이 추적 정보에는 이벤트 발생시간, API 호출내역, DB로 전송된 SQL 문, 파라메터와 필드 값, 오류와 경고 등이 기록되어 여러분의 DB 애플리케이션의 문제점을 디버깅하고 해결하는데 유용하게 사용할 수 있습니다.

샘플에서는 데이터 조회(테이블 오픈) 시 애플리케이션과 DBMS의 통신내용을 모니터링 유틸리티(FireDAC Monitor)로 확인하고, DB 애플리케이션 디버깅 시 유용한 메터데이터(DBMS 객체 정보)를 이용해 테이블, 필드, 제너레이터, 스토어드 프로시저 목록을 조회해 봅니다.

3. 캐쉬를 이용한 업데이트와 자동증가필드(Identity) 적용

캐쉬 업데이트는 애플리케이션의 메모리 영역(즉, 데이터셋)에 업데이트 내역을 기록하고, DBMS에 한번에 업데이트(또는 일괄취소) 할 수 있는 기능입니다. 

캐쉬 업데이트를 사용하면 작업내용을 로컬에서 관리하므로 DBMS와의 트래픽을 줄일 수 있고, 사용자는 통신속도와 관계없이 빠른 작업이 가능합니다. 그리고 작업이력을 확인(변경된 레코드 조회, 변경된 항목의 이전 값 확인 등)하고, 작업 변경취소(마지막 작업 변경취소, 선택한 레코드 변경취소 등)을 FireDAC에서 제공하는 메소드를 이용해 손쉽게 구현할 수 있습니다.

샘플에서는 캐쉬 업데이트를 이용해 조회한 데이터를 메모리 상에서 편집(입력, 수정, 삭제) 후 업데이트 목록 표시, 변경취소, 일괄적용/취소 기능을 구현해 봅니다.

Array DML은 DBMS에 업데이트할 데이터를 배열 형태의 파라메터로 한번에 전송해 아주 빠르게 데이터를 입력할 수 있는 기능입니다.

Array DML을 사용하면 DBMS와 애플리케이션 사이의 통신비용을 줄이고 DBMS에 전송하는 요청 횟수를 현격히 줄입니다. 그 결과 실행 속도를 대폭 향상시킬 수 있습니다.

예를 들면, 1만건의 데이터 입력 시 반복 입력 작업을 트랜젝션으로 묶으면 20배 빨라지고, Array DML을 사용하면 다시 10배가 더 빨라집니다. 샘플을 통해 결과를 직접 확인해 보기 바랍니다.

FireDAC에는 검색옵션, 형식옵션, 업데이트옵션, 리소스옵션, 트랜젝션옵션 등의 수많은 옵션을 제공합니다.

이 글에서는 주요 옵션을 살펴봅니다. 주요 옵션을 살펴보고 필요한 옵션은 상세확인 해 여러분의 애플리케이션을 향상해 보기 바랍니다.

샘플에서는 데이터 지연 조회(DetailDelay), 데이터 페이징 단위 조회(RecsSkip, RecsMax)과 같은 고급 기능을 FireDAC 옵션을 이용해 손쉽게 구현해 봅니다.

커맨드 텍스트 전처리는 SQL 명령을 데이터베이스에 전달하기 전 파라메터를 치환하고, FireDAC 매크로 함수를 DBMS에 맞도록 치환하는 기능입니다.

전처리 기능은 아래 3 종류의 매크로 명령을 제공합니다.

• 매개변수를 확장할 수 있는 대체변수
• 한번 작성 후 다양한 DBMS에서 사용할 수 있는 SQL문 작성하는 이스케이프 시퀀스
• 연결된 DBMS에 따라 조건부로 실행되는 SQL문을 작성하는 조건부 대체 

FireDAC의 ETL은 Extract, Transform, Load의 약자로 아래의 역할을 의미합니다. 

• Extract(추출) : 같은 종 또는 이기종 데이터 소스로부터 데이터를 추출 
• Transform(변환) : 추출한 데이터를 분석용 데이터 형식 또는 입력쿼리로 변환
• Load(로드) : 최종 목적(데이터베이스, 운용 데이터 저장소, 데이터 마트, 또는 데이터 창고)으로 로드 

FireDAC ETL로 아래의 기능을 구현할 수 있습니다.(몇가지 예시입니다.) 

• Query문으로 조회한 데이터를 엑셀에서 사용할 수 있는 CSV 파일로 내보내기
• 텍스트파일의 데이터를 데이터베이스 테이블로 가져오기
• 데이터베이스에서 다른 데이터베이스로 데이터 이동하기

Local SQL은 DB로부터 애플리케이션의 메모리 상으로 가져온 데이터(데이터셋: TDataSet을 상속받은 객체)를 대상으로 다시 SQL 쿼리를 할 수 있는 기능입니다. Local SQL은 아래와 같이 사용할 수 있습니다. 

• 여러 이기종 DB들에 대한 쿼리 : 다양한 DB에서 가져온 여러 데이터셋을 대상으로 원하는 데이터 쿼리(조인 가능) 
• 인 메모리 데이터베이스 : TFDMemTable은 메모리상에 있는 데이터셋의 역할 
• 오프라인 모드 쿼리 : 원격 DB에 연결할 수 없는 경우에도, 이미 가져온 데이터셋을 대상으로 쿼리 실행 
• 데이터스냅 클라이언트 쿼리 : 데이터스냅 서버(미들웨어)에서 받아온 데이터셋을 대상으로 쿼리 실행 
• 간편한 마이그레이션 : 애플리케이션 내에서 써드파티를 통해 가져온 데이터셋 객체를 대상으로 쿼리 실행

(준비 중)

관련링크

• [데브기어] FireDAC 소개
• [유투브] FireDAC Skill Sprint 다시보기
• [온라인교육] FireDAC 무료 온라인 교육 안내

여러분의 FireDAC 애플리케이션에서 DBMS와 접속하기 위해서는 DBMS 제조사에서 제공하는 네이티브 클라이언트 드라이버를 설치해야 합니다. 네이티브 클라이언트 드라이버는 각 제조사 홈페이지를 통해 다운로드 받아 설치할 수 있습니다.

오라클 서버에 접속하기 위해서는 오라클 클라이언트 소프트웨어를 설치해야 합니다.

오라클 클라이언트 소프트웨어는 아래 2가지 방식으로 제공합니다.

• "Fat" 오라클 클라이언트 - 설치형 오라클 클라이언트 프로그램. 기본 오라클 홈경로에 설치된 오라클 드라이버 이용합니다.
• "Thin" 오라클 클라이언트 - 파일형 오라클 클라이언트 프로그램. 윈도우 PATH 또는 실행파일과 동일한 경로에 아래 라이브러리 복사해 사용합니다.

• oci.dll

• oraocci11.dll

• oraociei11.dll

• orasql11.dll

오라클 다운로드 페이지(http://www.oracle.com/technetwork/indexes/downloads/index.html)에서 Database > Instant Client 메뉴를 선택합니다.

델파이 개발환경에 맞는 Instant Client for Microsoft Windows (32-bit)를 선택합니다.

상단의 라이선스에 동의 하고 

본인의 오라클 서버 버전의 파일을 찾아 다운로드 합니다.(저는 11.2.0.2 버전의 오라클 서버와 연결합니다.) 

(로그인이 필요하니 오라클 계정이 없는 경우 계정 생성 후 로그인하여 진행합니다.)

zip 파일 다운로드 완료 후 압축을 해제합니다.

아래 4개 파일을 복사 후 RAD Studio 실행파일 경로(XE7 기준 기본경로: C:\Program Files (x86)\Embarcadero\Studio\15.0\bin)에 복사합니다.

(오라클에 접속할 애플리케이션의 실행파일 경로 또는 윈도우 PATH에 등록된 경로에 오라클 클라이언트 라이브러리가 있어야 합니다.)

• oci.dll

• oraocci11.dll

• oraociei11.dll

• orasql11.dll

새로운 프로젝트를 생성합니다.(File > New > VCL Form Application - Delphi)

아래의 화면과 표를 참고해 폼에 컴포넌트를 추가합니다.

3, 오라클 서버 연결

사전 준비사항

개발PC에서 오라클서버와 접속 가능해야 합니다. 오라클에서 제공하는 SQL Plus 툴(다운로드: 오라클 서버 버전과 맞는 SQLPlus 다운로드)을 이용해 오라클 서버와 접속을 확인합니다.

오라클 서버 연결 설정

폼(또는 데이터모듈) 위에 TFDConnection 컴포넌트를 추가하고 추가한 컴포넌트를 더블클릭 해 "FireDAC Connection Editor" 대화상자를 표시하고 아래 정보를 입력합니다.

• Driver ID : Ora
• Database : 오라클서버의 주소(형식: IP주소:Port/ServiceName, 예> 192.0.0.1:1521/orcl)
• User_Name : 오라클 계정
• Password : 오라클 계정의 비밀번호

테스트 버튼을 눌러 입력한 정보가 정확한지 확인합니다.(로그인 창이 나오면 OK 버튼을 누릅니다.)

Connection Editor 창의 OK 버튼을 눌러 설정을 저장합니다.

TFDConnection 컴포넌트의 LoginPromt 속성을 False로 설정 후 Connected 속성을 True로 설정해 연결합니다.

테이블 컴포넌트(FDTable1) 선택 후 TableName 속성에서 조회할 테이블을 선택합니다.

FDTable1의 Active 속성을 True로 설정합니다.

DBGrid1의 DataSource를 DataSourc1으로 설정 해 테이블의 데이터가 DBGrid에 표시되는지 확인합니다.

애플리케이션 배포 시 오라클 클라이언트 드라이버의 라이브러리 4종을 실행파일과 같은 경로로 함께 배포합니다.

위 파일을 복사해 개발환경이 아닌 PC에서 동작을 확인합니다.

참고

• Connect to Oracle Server(FireDAC) - 한글번역

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

6회차에서는 커맨드 텍스트 전처리에 관한 내용으로 진행합니다.

커맨드 텍스트 전처리란?

커맨드 텍스트 전처리는 SQL 명령을 데이터베이스에 전달하기 전 파라메터를 치환하고, FireDAC 매크로 함수를 DBMS에 맞도록 치환하는 기능입니다.

FireDAC 은 커맨드 텍스트 전처리 작업할 수 있는 3가지의 매크로 명령을 지원합니다.

• 대체변수(Substitution variables) : 파라메터 확장을 위해 SQL 문의 일부를 치환. 예를 들면 FROM절의 테이블이름과 SELECT 절의 필드명을 파라메터화 하려면 대체변수를 사용해야 함
• 이스케이프 시퀀스(Escape sequences) : 한번 작성하면 서로 다른 DBMS에서 그대로 사용할 수 있는 DBMS에 의존적이지 않은 SQL문 생성
• 조건부 대체(Conditional substitutions) : 연결된 DBMS에 따라 조건부로 실행되는 SQL 문 작성

대체변수

FDQuery1.SQL.Text := 'SELECT * FROM &TabName';
FDQuery1.MacroByName('TabName').AsRaw := 'Orders';
FDQuery1.Open;

• 위와 같이 매크로 변수(&TabName)를 이용해 SQL 문 작성 후  MacroByName 메소드를 이용해 내용을 치환할 수 있습니다.

이스케이프 시퀀스

FireDAC은 다음 5가지 이스케이프 시퀀스가 있습니다.

• 상수 치환
• 식별자 치환
• 조건부 대체
• Like 연산자 이스케이프 시퀀스
• 스칼라 함수

그중 상수 치환 이스케이프 시퀀스를 사용하면 DBMS의 구문 및 지역설정과 관계없이 커맨드 텍스트 상수를 작성할 수 있습니다. 예를 들면 아래와 같습니다.

• {d <날짜>} : {d 2014-08-30}은 Oracle에서 TO_DATE{'2014-08-30', 'yyyy-mm-dd'} 입니다.
• {t <시간>} : {t 14:30:00}은 SQL Server에서 CONVERT (DATETIME, '14 : 30 : 00 ', 114) 입니다.(hh24:mi:ss 형식으로 작성해야 합니다.)
• {id <식별자명>} : 식별자명이 DBMS의 고유 구문으로 치환됩니다.
  

조건부 대체

조건부 대체는 연결된 DBMS(또는 매크로 변수 값)에 따라 명령을 대체합니다. 예를 들면 아래와 같습니다.

• {IF Oracle} TO_CHAR{fi} {IF MSSQL} CONVERT {fi} : 오라클인 경우 TO_CHAR, MSSQL인 경우 CONVERT 명령어로 실행됩니다.

이 샘플에서는 총 2가지 기능을 소개합니다.

• 테이블을 선택 후 해당 테이블의 필드를 (다중)선택 하면 매크로의 대체변수를 이용해 SQL 쿼리를 작성해 데이터를 조회합니다.

• 이스케이프 시퀀스를 이용해 작성한 쿼리 수행 후 FireDAC 모니터를 통해 최종적으로 실행되는 SQL 쿼리와 비교합니다.

[샘플코드 받기 - 데브기어 github 페이지]

매크로 대체변수로 필드목록과 테이블명 선택 해 데이터 조회하기

첫번째 탭에 구현된 기능으로 테이블 목록에서 테이블 선택 후 필드(다중선택) 목록에서 조회할 필드를 체크 후 "선택 데이터 표시" 버튼을 누르면 그리드에 데이터가 표시됩니다.

쿼리컴포넌트에는 아래와 같이 필드목록(&FieldList)와 대상 테이블명(&TableName)을 매크로 대체변수로 작성했습니다.

SELECT &FieldList FROM &TableName

델파이에서는 아래 코드와 같이 Macro 값을 설정하고 쿼리를 실행하면 SQL 문이 실행되기 전 필드목록과 테이블명이 치환되어 SQL 문이 실행됩니다.

  DM.qrySelect.MacroByName('FieldList').AsRaw := FieldList;
  DM.qrySelect.MacroByName('TableName').AsRaw := ListBox1.Selected.Text;
  DM.qrySelect.Open;

이스케이프 시퀀스는 

1. FireDAC 매크로 함수를 이용해 DBMS에 의존적이지 않은 SQL문을 작성합니다.
2. 매크로 함수가 포함된 SQL 문은 실행 전 DBMS에 맞는 DBMS 함수로 치환되어 SQL 문이 실행됩니다.

쿼리 컴포넌트에는 아래와 같이 매크로 함수가 포함된 SQL문을 작성했습니다.

SELECT {Current_Date()} as Today, c.*
  FROM &TabNam c
 WHERE {Extract(Year, c.SaleDate)} = {e 1988}

애플리케이션을 실행하고 FireDAC 모니터링 기능을 이용해 처리된 SQL 문을 확인하면 아래와 같이 DBMS의 함수로 치환되어 SQL 문이 실행됩니다.

매크로 함수는 아래와 같습니다.

• Character Macro Functions
• Numeric Macro Functions
• Date and Time Macro Functions
• System Macro Functions
• Convert Macro Functions

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

5회차에서는 FireDAC의 캐스캐이딩 옵션에 대해 소개하고 살펴봅니다.

FireDAC에는 5종류의 옵션 그룹을 제공합니다.

• FetchOptions : DBMS에서 데이터를 어떻게 취득할지 제어하는 검색 옵션입니다.
• FormatOptions : DBMS의 데이터형식을 FireDAC 데이터 형식으로 또는 반대로 매핑하는 방법을 제어하는 형식 옵션입니다.(자세한 내용은 "Data Type Mapping"을 참조하세요.)
• UpdateOptions : DBMS에 업데이트 전송 방법을 제어하는 업데이트 옵션입니다. 업데이트 시 테이블의 모든 필드를 업데이트하거나 변경된 필드만 업데이트 할 수 있습니다.
• ResourceOptions : 시스템 리소스 사용과 데이터셋의 지속성을 제어하는 자원 옵션입니다. 예를 들면 FireDAC Phys 레이어 명령을 비동기 적으로 실행 또는 차단할 수 있습니다.
• TxOptions : 트랜젝션 실행방법을 제어하는 트랜젝션 옵션입니다. 

위의 옵션은 Manager > Connection > DataSet/Command로 캐스캐이딩(위에서 아래로 적용) 됩니다. 즉, TFDConnection에 옵션을 설정하면 해당 연결을 사용하는 TFDQuery, TFDTable도 동일한 옵션이 적용됩니다.(일부 옵션 제외)

FireDAC 카테고리 별 주요옵션

다음은 FireDAC 주요옵션을 카테고리별로 나열한 것입니다. 각 옵션에 대한 자세한 내용은 항목 아래 기술문서 링크에 방문해 상세 설명을 보시기 바랍니다.

검색옵션(FetchOptions)

• 취득 방법 ( CursorKind , Mode , RowsetSize ). 예를 들어, 결과 세트의 모든 레코드를 한 번에 검색 할 수 주문형 레코드를 검색 할 수 있습니다. 
• 자원 보존 방법 ( Unidirectional , AutoClose , Cache , AutoFetchAll ). 
• BLOB 필드 중첩 된 레코드 메타 데이터 검색 및 캐시 방법 ( Items , Cache ). 
• 마스터/디테일 데이터셋 관계의 처리 방법 ( DetailDelay , DetailOptimize , DetailCascade ). 
• 행 집합 페이징 ( RecsMax , RecsSkip ). 
• TFDTable 작동 모드 ( CursorKind , LiveWindowParanoic , LiveWindowFastFirst ). 
• 데이터 집합의 레코드를 세는 방법 ( RecordCountMode ).

TFDFetchOptions 기술문서 - http://docwiki.embarcadero.com/Libraries/XE7/en/FireDAC.Stan.Option.TFDFetchOptions

형식옵션(FormatOptions)

• 문자열 데이터 형식 ( StrsEmpty2Null , StrsTrim , StrsTrim2Len , InlineDataSize , MaxStringSize ) 
• 숫자 데이터 형식 ( MaxBcdPrecision , MaxBcdScale , Round2Scale ) 
• 시간 데이터 형식 ( Round2Scale ) 
• 일반적인 데이터 형식 매핑 ( MapRules , OwnMapRules , DefaultParamDataType ). 예를 들어 NUMERIC (9, 0)의 열을 ftInteger 컬럼에 맵핑 할 수 있습니다. 
• 필드 형식 ( FmtDisplayDateTime , FmtDisplayDate , FmtDisplayTime , FmtDisplayNumeric , FmtEditNumeric ) 
• 데이터 집합의 정렬 ( SortLocale , SortOptions ) 
• 식별자 따옴표 ( QuoteIdentifiers )

TFDFormatOptions 기술문서 - http://docwiki.embarcadero.com/Libraries/XE7/en/FireDAC.Stan.Option.TFDFormatOptions

업데이트옵션(UpdateOptions)

• 데이터 편집 허용 ( EnableDelete , EnableInsert , EnableUpdate , ReadOnly , CheckRequired , CheckReadOnly , CheckUpdatable ). 여기에는 TField.ReadOnly 과 TField.Required 도 영향을줍니다. 
• 데이터베이스 레코드 잠금 ( LockMode , LockPoint , LockWait ). 
• 자동 증가 필드에 대한 데이터베이스 생성기와 시퀀스의 사용 ( FetchGeneratorsPoint , GeneratorName ). 여기에는 TField.AutoGenerateValue 도 영향을줍니다. 
• 업데이트 사후 명령의 생성 ( UpdateChangedFields , UpdateNonBaseFields , UpdateMode , FastUpdates ). 여기에는 TField.ProviderFlags 과 TField.Origin 도 영향을줍니다. 
• 데이터의 업데이트 ( RefreshMode , RefreshDelete ). 
• 업데이트 포스트 결과 확인 ( CountUpdatedRecords ).

TFDUpdateOptions 기술문서 - http://docwiki.embarcadero.com/Libraries/XE7/en/FireDAC.Stan.Option.TFDUpdateOptions

리소스옵션(ResourceOptions)

• SQL 명령 텍스트 전처리 ( EscapeExpand , MacroCreate , MacroExpand , ParamCreate , ParamExpand , PreprocessCmdText , UnifyParams ). 
• 명령의 준비 ( DirectExecute , DefaultParamType ). 
• 명령 실행 ( CmdExecMode , CmdExecTimeout , ArrayDMLSize ). 
• 자원 관리 ( SilentMode ). 
• 데이터 집합 지속성 ( Persistent , Backup , BackupExt , BackupFolder , DefaultStoreExt , DefaultStoreFolder , DefaultStoreFormat , StoreVersion , StoreItems ).

TFDResourceOptions 기술문서 - http://docwiki.embarcadero.com/Libraries/XE7/en/FireDAC.Stan.Option.TFDResourceOptions

트랜젝션옵션(TxOptions)

• 독점적 수준 ( Isolation ) 
• 업데이트 기능 ( ReadOnly ) 
• 자동 커밋 ( AutoCommit , AutoStart , AutoStop , StopOptions ) 
• DBMS 고유의 파라미터 ( Params ) 
• 액션 연결 해제 ( DisconnectAction ) 중첩 ( EnableNested )

TFDTxOptions 기술문서 - http://docwiki.embarcadero.com/Libraries/XE7/en/FireDAC.Stan.Option.TFDTxOptions

FireDAC 옵션 샘플프로그램

이 샘플에서는 FetchOptions을 이용해 아래 3가지 기능을 구현했습니다.

• 테이블에 데이터가 많은 경우 신속하게 화면에 표시하기 위해 데이터를 나눠서 가져오기(FetchOptions.RowsetSize, FetchOptions.Mode 이용)
• 데이터를 페이징 단위(중간의 데이터 만)로 조회(FetchOptions.RecsSkip, RecsMax 이용)
• 마스터/디테일 형식의 화면에서 키보드로 목록을 빠르게 움직여도 마지막에 위치한 상세정보만 표시해 불필요한 데이터 조회 방지(FetchOptions.DetailDealy 이용)

[샘플코드 받기 - 데브기어 github 페이지]

  qryEmployee.Close;
  if TCheckBox(Sender).Checked then
  begin
    qryEmployee.FetchOptions.RowsetSize := 3;
    qryEmployee.FetchOptions.Mode := TFDFetchMode.fmManual;
  end
  else
  begin
    qryEmployee.FetchOptions.Mode := TFDFetchMode.fmOnDemand;
  end;
  qryEmployee.Open;
  btnFetchNext.Enabled := TCheckBox(Sender).Checked;

  qryEmployee.Close;
  qryEmployee.FetchOptions.RecsSkip := 10;
  qryEmployee.FetchOptions.RecsMax := 10;
  qryEmployee.Open;

  if TCheckBox(Sender).Checked then
    qryProject.FetchOptions.DetailDelay := StrToIntDef(Edit1.Text, 300)
  else
    qryProject.FetchOptions.DetailDelay := 0;

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

  with FDQuery1 do begin
    SQL.Text := 'insert into Customers (ID, RegionID, Name, Note) values (:ID, :RegionID, :Name, :Note)';
    // Set up parameter types
    Params[0].DataType := ftInteger;
    Params[1].DataType := ftInteger;
    Params[2].DataType := ftString;
    Params[2].Size := 40;
    Params[3].DataSize := ftMemo;
    // Set up parameters' array size
    Params.ArraySize := 10000;
    // Set parameter values
    for i := 0 to 10000 - 1 do begin
      if i mod 100 = 0 then
        // force PK violation
        Params[0].AsIntegers[i] := i - 1
      else
        Params[0].AsIntegers[i] := i;
      Params[1].AsIntegers[i] := GetRegionIdForCustomer(i);
      Params[2].AsStrings[i] := 'Somebody ' + IntToStr(i);
      Params[3].Clear(i);
    end;
    // Execute batch
    Execute(10000, 0);
  end;

var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');

  StopWatch := TStopWatch.StartNew;

  for I := 0 to NUM_INSERTS - 1 do
  begin
    FDQuery1.ParamByName('Field1').AsInteger := I;
    FDQUery1.ParamByName('Field2').AsString := 'Str' + I.ToString;
    FDQuery1.ExecSQL;
  end;

  StopWatch.Stop;
  Memo1.Lines.Add('Insert STD : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');

var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');

  StopWatch := TStopWatch.StartNew;

  // Transaction 추가
  FDConnection1.StartTransaction;
  try
    for I := 0 to NUM_INSERTS - 1 do
    begin
      FDQuery1.ParamByName('Field1').AsInteger := I;
      FDQUery1.ParamByName('Field2').AsString := 'Str' + I.ToString;
      FDQuery1.ExecSQL;
    end;
  finally
    FDConnection1.Commit;
  end;

  StopWatch.Stop;
  Memo1.Lines.Add('Insert STD(Transaction) : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');

var
  I: Integer;
  StopWatch: TStopwatch;
begin
  FDConnection1.ExecSQL('DELETE FROM Test');

  StopWatch := TStopWatch.StartNew;

  FDConnection1.StartTransaction;
  try
    FDQuery1.Params.ArraySize := NUM_INSERTS;
    for I := 0 to NUM_INSERTS - 1 do
    begin
      FDQuery1.ParamByName('Field1').AsIntegers[I] := I;
      FDQUery1.ParamByName('Field2').AsStrings[I] := 'Str' + I.ToString;
    end;
    FDQuery1.Execute(NUM_INSERTS);
  finally
    FDConnection1.Commit;
  end;

  StopWatch.Stop;
  Memo1.Lines.Add('Insert ArrayDML : ' + StopWatch.ElapsedMilliseconds.ToString + ' ms');

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

3회차에서는 FireDAC의 Cached Updates와 Auto-Inc Fields에 대해 진행했습니다.

캐쉬를 이용한 업데이트

캐쉬 업데이트는 애플리케이션의 메모리 영역(즉, 데이터셋)에 업데이트 내역을 기록하고, DBMS에 한번에 업데이트하거나 일괄취소할 수 있는 기능입니다.

캐쉬 업데이트를 사용하면 작업내용을 로컬에서 관리하므로 DBMS와의 트래픽을 줄일 수 있고, 사용자는 인터넷속도와 관계없이 빠르게 작업할 수 있습니다. 그리고 부가적으로 작업이력을 확인(변경된 레코드 조회, 변경된 값 확인 등)하고, 작업을 되돌리는 기능(최종작업 되돌리기, 선택 레코드 되돌리기 등)등을 제공되는 메소드를 이용해 손쉽게 구현할 수 있습니다.

캐쉬 업데이트를 적용하려면 데이터셋(예> TFDQuery, TFDTable)의 CachedUpdates 속성을 True로 설정합니다.

캐쉬 업데이트는 분산 캐쉬 업데이트 모드와 중앙 캐쉬 업데이트 모드를 제공합니다.

• 분산 캐쉬 업데이트 모드 - 각 데이터셋이 다른 데이터셋과 관계없이 변경사항을 추적합니다.(기본 모드)
• 중앙 캐쉬 업데이트 모드 - 여러 데이터셋을 단일 변경로그에 시간순으로 기록합니다.(중앙 캐쉬 업데이트 모드 자세히 보기)

캐쉬 업데이트 주요 메소드

다음은 캐쉬 업데이트에서 사용하는 주요 메소드입니다. 메소드에 대한 설명만 기록합니다. 메소드의 상세설명과 사용법은 FireDAC 기술문서 - Caching Updates(FireDAC) 를 참고하기 바랍니다.

업데이트 내역 추적

캐쉬 업데이트 사용 시 업데이트 내역을 추적할 수 있고, 변경을 취소할 수 있습니다.

• UpdatesPending - 변경 로그가 있으면 True 를 반환합니다. 
• ChangeCount - 변경된 레코드 수를 반환합니다.
• UpdateStatus - 현재 레코드의 변경 유형을 반환합니다. 
• FilterChanges - 레코드를 변경 유형으로 필터링 할 수 있도록합니다.

• SavePoint - 변경 로그의 현재 상태를 설정 / 가져옵니다. 
• RevertRecord - 현재 레코드를 이전 상태로 되돌립니다. 
• UndoLastChange - 마지막으로 수정 한 레코드로 이동하고 레코드를 이전 상태로 되돌립니다. 
• CancelUpdates - 변경 로그에 포함 된 모든 레코드를 취소합니다.

업데이트 적용

캐쉬의 변경을 데이터베이스에 적용하려면 ApplyUpdates 메소드를 사용합니다. 레코드 적용 시 예외가 발생한 경우 그 예외는 레코드에 연결됩니다. 

ApplyUpdates 메소드는 다음 특징이 있습니다.

• ApplyUpdates 시 예외를 발생하지 않고 리턴값으로 예외 수 반환
• 트랜젝션으로 업데이트가 적용되지 않는다. 애플리케이션에서 ApplyUpdates로 적용해야 한다.
• 즉시 업데이트와 데이터셋 처리 방식은 동일하다.

FDQuery1.Append;
...
FDQuery1.Post;
FDConnection1.StartTransaction;
iErrors := FDQuery1.ApplyUpdates;
if iErrors = 0 then begin
  FDQuery1.CommitUpdates;
  FDConnection1.Commit;
end
else
  FDConnection1.Rollback;

캐시를 이용한 업데이트에 대한 자세한 내용은 FireDAC 기술문서 - Caching_Updates를 참고하기 바랍니다.

FireDAC은 새로운 레코드 추가 시 자동증가 컬럼에 새로운 값을 할당 할 수 있습니다.(즉시 업데이트와 캐쉬 업데이트 모두에서 동작) 

DBMS의 자동 증가 필드는 다음과 같이 특수한 Identity(또는 유사한) 컬럼 데이터형식을 사용하거나 제너레이터(또는 시퀀스)와 테이블 트리거를 사용해 구현됩니다.

FireDAC에는 DBMS 별로 자동 인식 방식과 수동 지정 방식으로 처리해야 합니다.

- FireDAC 기술문서 참고 - http://docwiki.embarcadero.com/RADStudio/XE7/en/Auto-Incremental_Fields_(FireDAC)

자동 인식

FireDAC에서 자동 증가 데이터 형식 컬럼을 자동 인식하고 아래와 같이 설치됩니다.

• TField.DataType = dtInt32 또는 dtUInt32의 경우 ftAutoInc (TFDAutoIncField), 그렇지 않은 경우는 수치 데이터 형 ftXxxx 중 하나 
• TField.Required = False 
• TField.ReadOnly = True 
• TField.ProviderFlags = [pfInWhere] 또는 열이 기본 키 구성 요소의 경우 [pfInWhere, pfInKey]

수동 지정

• UpdateOptions.AutoIncFields 속성에서 자동 증가 컬럼을 설정
• TFDAutoIncField를 직접 만듭니다.(컬럼이 ftAutoInc / ftInteger / ftLongWord 필드 형이여야 함)
• TFieldAutoGenerateValue를 자동 증가 필드에 해당하는 arAutoInc로 설정(ProviderFlags, Required, ReadOnly 설정이 필요할 수 있음)

[샘플코드 받기 - 데브기어 github 페이지]

자동증가 설정(데이터모듈 생성 시)

데이터베이스와 연결된 상태에서 데이터셋(TFDQuery, TFDTable)에서 필드를 추가합니다.

(모든 필드 추가 : 데이터셋 컴포넌트 > 우측 마우스 메뉴 > Fields Editor > 우측 마우스 > Add all fields)

자동 증가 컬럼(SEQ) 선택 후 AutoGenerateValue 속성을 arAutoInc로 설정합니다. 

코드로 진행 시 아래와 같습니다.

SEQ(자동증가 컬럼) 선택 후 AutoGenerateValue 속성을 arAutoInc로 설정합니다. 아래의 코드로 설정 가능합니다.

procedure TDM.DataModuleCreate(Sender: TObject);
begin
  // Auto-Inc 설정
  FDQuery1SEQ.AutoGenerateValue := arAutoInc;
  FDQuery1SEQ.Required := False;
  FDQuery1SEQ.ReadOnly := True;

  // CachedUpdates 설정
  FDQuery1.CachedUpdates := True;
end;

캐쉬 업데이트 - 일괄적용 / 일괄취소

procedure TForm2.btnApplyUpdatesClick(Sender: TObject);
var
  iErr: Integer;
begin
  DM.FDConnection1.StartTransaction;

  // ApplyUpdates는 오류를 발생하지 않음
  iErr := DM.FDQuery1.ApplyUpdates(-1);
  if iErr = 0 then
  begin
    DM.FDQuery1.CommitUpdates; // 변경로그 지우기
    DM.FDConnection1.Commit;
  end
  else
    DM.FDConnection1.Rollback;

  DM.FDQuery1.Refresh;
end;

procedure TForm2.btnCancelUpdatesClick(Sender: TObject);
begin
  DM.FDQuery1.CancelUpdates;
  DM.FDQuery1.Refresh;
end;

  // 캐쉬 보기
  if DM.FDQuery1.Active then
  begin
    DM.FDMemTable1.CloneCursor(DM.FDQuery1, True);
    DM.FDMemTable1.FilterChanges := [rtModified, rtInserted, rtDeleted];
  end;

  // 이전 값 확인
  ShowMessage(format('이전 값: %s  ->  새로운 값: %s', [
                      DM.FDQuery1.FieldByName('FIELD1').OldValue,
                      DM.FDQuery1.FieldByName('FIELD1').Value]));

  // 마지막 변경 취소
  DM.FDQuery1.UndoLastChange(True);

  // 선택 레코드 변경 취소
  DM.FDQuery1.RevertRecord;

  // 저장점 생성
  FSavePoint := DM.FDQuery1.SavePoint;

  // 저장점으로 되돌리기
  if FSavePoint > 0 then
    DM.FDQuery1.SavePoint := FSavePoint;

엠바카데로에서 FireDAC Skill Sprint 웨비나(1월 23일 ~ 3월 27일: 매주 금요일 10시)를 진행하고 있습니다.

이 글에서는 웨비나 다시보기와 함께 웨비나 일부 내용을 샘플코드와 함께 소개합니다. 하단 온라인 기술 도움말 링크를 통해 더 자세한 내용을 추가학습하시기 바랍니다.

2회차에서는 FireDAC의 추적과 모니터링에 대한 내용으로 진행합니다.

FireDAC의 추적기능을 이용하면 애플리케이션과 데이터베이스 사이의 통신내용을 상세하게 보거나 기록할 수 있습니다. 

이 추적 정보에는 이벤트 발생시간, API 호출내역, DB로 전송된 SQL, 파라메터와 필드 값, 오류와 경고 등이 기록되어 여러분의 DB 애플리케이션으 문제점을 디버깅하고 해결하는데 유용하게 사용할 수 있습니다.

(주의 : 추적과 모니터링 기능은 애플리케이션의 성능에 영향을 줄 수 있습니다. 디버그 모드에서만 추적기능이 동작하도록 구성하기 바랍니다.)

추적 모니터링 컴포넌트

FireDAC에서는 추적 모니터링 기능을 아래 3종류의 컴포넌트로 제공합니다.

• TFDMoniFlatFileClientLink : 추적 결과를 텍스트 파일로 기록합니다. 애플리케이션이 완료되면 생성된 추적기록 파일 목록이 표시됩니다.
• TFDMoniRemoteClientLink : 추적 결과를 FDMonitor 유틸리티에 출력(원격지 가능)합니다.(추적 시작 전에 FDMonitor를 미리 실행해야 추적이 기록됩니다.)
• TFDMoniCustomClientLik : 추적 결과를 커스텀 이벤트핸들러를 통해 출력합니다. 애플리케이션에서는 OnOut 이벤트를 이용해 직접 추적 결과를 기록해야 합니다.

1. 추적 모니터링 컴포넌트(TFDMoniXXXXClientLink)를 폼(또는 데이터모듈)에 추가합니다.
2. 추가한 컴포넌트의 Tracing 속성을 True로 설정(기록을 위한 속성 추가설정)
3. 연결 컴포넌트(TFDConnection)의 연결속성에서 MonitorBy 항목을 선택(FlatFile, Remote, Custom) 합니다.
   

추적 항목 선택

추적 항목은 추적 모니터링 컴포넌트의 EventKinds 속성을 통해 선택할 수 있습니다. 각 항목은 아래와 같습니다.(참고 : Debugging and Reporting Environment Questions (FireDAC))

• LiveCycle : 객체의 생성 / 소멸. 예를 들어, IFDPhysConnection가 생성됩니다. 
• Error : DBMS 오류 
• ConnConnect : 연결 열기 및 닫기 
• ConnTransact : 시작 / 커밋 / 롤백 
• ConnService : 특별 이벤트 
• CmdPrepare : IFDPhysCommand.Prepare 호출 
• CmdExecute : IFDPhysCommand.Execute 또는 Open 호출 
• CmdDataIn : 명령 매개 변수 값 
• CmdDataOut : 결과 집합 행 
• AdaptUpdat :​​ 업데이트 후 처리 모든 정보 
• Vendor : 낮은 수준 DBMS API 호출 
• Component : 고레벨 이벤트

추적과 모니터링에 대해 더 자세한 내용은 FireDAC 기술문서 - Tracing and Monitoring(FireDAC)을 참고하기 바랍니다.

FireDAC은 데이터베이스의 메타데이터를 조회할 수 있습니다.

메타데이터 쿼리 - TFDConnection 사용

다음과 같이 데이터베이스 오브젝트 이름 목록을 손쉽게 조회할 수 있는 메소드를 제공합니다.

• GetCatalogNames - 카탈로그 목록 
• GetSchemaNames - 스키마 목록 
• GetTableNames - 테이블 및 뷰 목록 
• GetFieldNames - 테이블 필드 목록 
• GetKeyFieldNames - 테이블 기본 키 목록 
• GetGeneratorNames - 발전기 / 시퀀스 목록 
• GetPackageNames - 패키지 목록 
• GetStoredProcNames - 저장 프로 시저 목록

사용 예제는 아래와 같습니다.(Memo1에 테이블명 목록을 출력)

FDConnection1.GetTableNames('Northwind', 'dbo', '', Memo1.Lines);

메타데이터 쿼리 - TFDMetaInfoQuery 사용

TFDMetaInfoQuery 컴포넌트는 메타데이터를 조회할 수 있는 데이터셋 컴포넌트입니다.

연결 설정 후 MetaInfoKind 속성만 연결하면 데이터셋을 열수 있습니다.(추가 옵션으로 CatalogName, SchemaName, BaseObjectName, ObjectName 속성을 설정합니다.)

추적과 모니터링, 메타데이터 샘플 프로그램 소개

이 샘플 프로그램에서는 아래 기능을 확인합니다.

• 추적 & 모니터링 기능을 확인합니다.

• DBMS 연결정보를 메모에 출력합니다.

• 메타데이터

• 테이블 목록, 필드목록, 제너레이터 목록, 스토어드프로시저 목록 조회

• TFDConnection의 메소드와 TFDMetaInfoQuery를 이용합니다.

[샘플코드 받기 - 데브기어 github 페이지]

• 폼(또는 데이터 모듈)에 추적 모니터링 컴포넌트 추가
• FDConnection1의 연결속성 중 MonitorBy 항목을 추가한 추적 모니터링 컴포넌트 종류(Remote, FlatFile, Custom)로 선택
• 테스트 주의사항
• 원격 모니터링(Remote)- 애플리케이션 실행 전 FDMonitor 유틸리티(Tools > FireDAC Monitor)를 먼저 실행할 것
• 파일 모니터링(FlatFile) - 애플리케이션 종료 후 실행파일과 같은 경로의 Trace.txt 파일에 로그가 기록됨

procedure TForm2.Button1Click(Sender: TObject);
begin
  // 원격 모니터링
  DM.FDMoniRemoteClientLink1.Tracing := False;
  DM.FDConnection1.Params.MonitorBy := TFDMonitorBy.mbRemote;
  DM.FDMoniRemoteClientLink1.Tracing := True;

  DM.FDTable1.Close;
  DM.FDTable1.Open;
end;

procedure TForm2.Button2Click(Sender: TObject);
begin
  // 파일 모니터링
  DM.FDMoniFlatFileClientLink1.Tracing := False;
  DM.FDConnection1.Params.MonitorBy := TFDMonitorBy.mbFlatFile;
  DM.FDMoniFlatFileClientLink1.FileName := TPath.Combine(TPath.GetLibraryPath, 'trace.txt');
  DM.FDMoniFlatFileClientLink1.Tracing := True;

  DM.FDTable1.Close;
  DM.FDTable1.Open;
end;

DM.FDConnection1.GetInfoReport(Memo1.Lines);

// TFDConnection 메타데이터 메소드 이용
procedure TForm2.Button4Click(Sender: TObject);
var
  MetaType: string;
begin
  MetaType := (Sender as TButton).Caption;
  if MetaType = 'GetTableNames' then
    DM.FDConnection1.GetTableNames('', '', '', Memo2.Lines)
  else if MetaType = 'GetFieldNames' then
    DM.FDConnection1.GetFieldNames('', '', 'EMPLOYEE', '', Memo2.Lines)
  else if MetaType = 'GetGeneratorNames' then
    DM.FDConnection1.GetGeneratorNames('', '', '', Memo2.Lines)
  else if MetaType = 'GetStoredProcName' then
    DM.FDConnection1.GetStoredProcNames('', '', '', '', Memo2.Lines)
  ;
end;

// TFDMetaInfoQuery 컴포넌트 이용
procedure TForm2.Button5Click(Sender: TObject);
var
  MetaType: string;
begin
  DM.FDMetaInfoQuery1.Close;

  MetaType := (Sender as TButton).Caption;
  if MetaType = 'GetTableNames' then
    DM.FDMetaInfoQuery1.MetaInfoKind := TFDPhysMetaInfoKind.mkTables
  else if MetaType = 'GetFieldNames' then
  begin
    DM.FDMetaInfoQuery1.MetaInfoKind := TFDPhysMetaInfoKind.mkTableFields;
    DM.FDMetaInfoQuery1.ObjectName := 'EMPLOYEE';
  end
  else if MetaType = 'GetGeneratorNames' then
    DM.FDMetaInfoQuery1.MetaInfoKind := TFDPhysMetaInfoKind.mkGenerators
  else if MetaType = 'GetStoredProcName' then
    DM.FDMetaInfoQuery1.MetaInfoKind := TFDPhysMetaInfoKind.mkProcs
  ;

  DM.FDMetaInfoQuery1.Open;
end;

관련링크

• FireDAC 기술문서 - Tracing and Monitoring
• FireDAC 기술문서 - DBMS 환경 레포팅(DBMS Environment Reports)
• FireDAC 기술문서 - 메타데이터 질의(Querying Metadata)
• [유투브] FireDAC Skill Sprint 다시보기
  
• [온라인교육] FireDAC 무료 온라인 교육 안내